Etepic

'****************************************************************
'*  Name    : PwmROLE.BAS                                      *
'*  Author  : [select VIEW...EDITOR OPTIONS]                    *
'*  Notice  : Copyright (c) 2024 [select VIEW...EDITOR OPTIONS] *
'*          : All Rights Reserved                               *
'*  Date    : 10.11.2024                                        *
'*  Version : 1.0                                               *
'*  Notes   : PIC16F1827 PWM DC Motor Kontrol                   *
'*          :                                                   *
'****************************************************************
    ASM
    __config _CONFIG1, _FOSC_INTOSC & _WDTE_OFF & _PWRTE_ON & _MCLRE_OFF & _CPD_ON & _BOREN_OFF & _CLKOUTEN_OFF & _IESO_ON & _FCMEN_OFF    
    __config _CONFIG2, _WRT_OFF & _PLLEN_ON & _LVP_OFF & _STVREN_OFF 
    endasm

    OSCCON = %11110000      '8 mhz internal clock, PLL on     
    ANSELA = %00011111      ' AN on PortA.0 analog
    ANSELB = %00000000      ' Digital inputs
    
    OPTION_REG.7=0
    'WPUA   = %11000000
    'WPUB   = %00110010
    
    DEFINE OSC 32
    DEFINE ADC_BITS 10     ' 10 bit A/D Conversion
    DEFINE ADC_CLOCK 1
    DEFINE ADC_SAMPLEUS 10 ' 5 uS A/D sample time

'///////////////////////////Analoglar///////////////////////////////      
    Symbol GODONE    = ADCON0.1  'Dönüştürme Durum Biti Devam ediyor = 1
    Symbol ADONE     = ADCON0.0  'Dönüştürme Modülü Etkin = 1
    Symbol ADIF      = PIR1.6      'ADC okuma bitti kesme bayrağı 
    'ADCON1 = 128
    'ADCON1 = %10100011
    'FVRCON = %10000011
    FVRCON = 0'$83
    ADCON1 = $D0
   	DACCON0 = 0
    DACCON1 = 0
    CM1CON0 = 0
    CM2CON0 = 0
    CM1CON1 = 0
    CM2CON1 = 0
    CPSCON0 = 0
    'RCSTA = $90   ' Enable serial port & continuous receive
    'TXSTA = $24   ' Enable transmit, BRGH = 1
    'SPBRG = 64    ' 9600 Baud @ 32MHz, 0,04%
    'SPBRGH = 3
    'BAUDCON.3 = 1 ' Enable 16 bit baudrate generator

    Symbol GIE       = INTCON.7    'genel kesmeler aktif                         
    Symbol PEIE      = INTCON.6    'Çevresel kesmeler aktif
    Symbol RCIE      = PIE1.5      'EUSART alma kesmesi              
    Symbol RCIF      = PIR1.5      'EUsart Kesme Bayrağı               
    Symbol SPEN      = RCSTA.7    'Seri Bağlantı Noktası Etkin = 1
    Symbol CREN      = RCSTA.4    'Sürekli veri alma etkin = 1
    Symbol OERR      = RCSTA.1    'Sürekli veri alma etkin = 1
    
    PEIE             = 0  'Çevresel Kesmeler Aktif                                                                                
    SPEN             = 0  'Seri Bağlantı Noktası Etkin = 1
    CREN             = 0  'Sürekli veri alma etkin = 1
    CREN             = 0

    RCIE             = 0  'EUsart Alma Kesmesi Aktif  = 1

    GIE              = 0  'Tüm kesmeler açık
    'ON INTERRUPT GOTO KESME 'komut satırını ekle programa (BASLA satırından bir evvele koyabilirsin)
        
    Porta = 0 
    Portb = 0 
    TRISA = %00011111   
    TRISB = %00010110
    WPUB  = %00010110
    
    MDCON=0                'modülator çıkışı iptal
    MDSRC=0                'modülasyon kaynak seçimi                 pwm sayfa 205 ten başlıyor
    MDCARH=0               'modülasyon yüksek biti
    MDCARL=0               'modülasyon düşük biti
    CCP1CON= %00001100     'pwm moduna ve tek pin çıkışına ayarlandı
    CCPTMRS=0              'tüm ccp lere tmr2  seçildi
    CCPR1L=0 
    CCPR1H=0
    T2CON=%00000101        'Prescaller / 16, Timer2 ON  'ccp1 için prescaller ayarlandı ve t2 devreye alındı
    PR2=249

    'Portb.3 Pwm Cıkıs
    Symbol Rly1    = Portb.7
    Symbol Rly2    = Portb.6
    Symbol Ttk1    = Portb.1
    Symbol Ttk2    = portb.2
    Symbol Ttk3    = portb.4
    Symbol YAkm    = portb.5
    
    Deger var word
    Dongu var byte
    Kanal var byte
    Ang1  var word
    Ang2  var word
    Ang3  var word
    Ang4  var word
    Ang5  var word
    
    OrtDgr var word
    Tmp1   var byte
    PwmDuty var word
    KnmMtr var byte
    X      var word
    YAkmSay    var word
    
    CCPR1L=0 
    CCPR1H=0 
    PwmDuty = 0
    KnmMtr = 0 
    YAkmSay = 100
    low Rly1
    low Rly2
'===============================================================================
'===============================================================================
basla:
      gosub AdcOku
      if Ttk1 = 0 and PwmDuty = 0 then
      low Rly2:high Rly1
      gosub YkrRampa
      endif
      if Ttk2 = 0 and PwmDuty = 0 then
      low Rly1:high Rly2
      gosub YkrRampa
      endif
      if Ttk1 = 1 and Ttk2 = 1 and PwmDuty != 0 then
      gosub AsgRampa
      endif  
      'pause 300
goto basla
'===============================================================================
'===============================================================================
RTemp1   var word
RTemp2   var word
Bkl      var word
YkrRampa:
Bkl = 2
'Ang2 = 1000
for PwmDuty = 0 to Ang2
    pause Bkl
    gosub PwmVer
next PwmDuty
Return
'===============================================================================
'===============================================================================
AsgRampa:
Bkl = 2
'Ang2 = 1000
for PwmDuty = ang2 to 1 Step -1
    pause Bkl
    gosub PwmVer
next PwmDuty
PwmDuty = 0
gosub PwmVer
Low Rly1
Low Rly2
Return
'===============================================================================
'===============================================================================
PwmVer:
if CCP1CON.2= 0 then CCP1CON.2= 1
if CCP1CON.3= 0 then CCP1CON.3= 1
    X = PwmDuty 
    CCP1CON.4 = x.0
    CCP1CON.5 = x.1
    CCPR1L = (X>>2)
return
'===============================================================================
'===============================================================================
AdcOku:
    For Kanal = 0 to 4
        OrtDgr = 0 
        for Dongu = 0 to 29
            lookup Kanal,[0,4,8,12,16], ADCON0
            ADIF   = 0
            ADONE  = 1  'Dönüştürme Modülü Etkin = 1
            GODONE = 1
            while GODONE = 1
            wend
            ADONE  = 0
            Deger = (ADRESh*256) + ADRESL 
            OrtDgr = OrtDgr + Deger
        next Dongu   
        OrtDgr = OrtDgr / 30
        if Kanal = 0 then     'Motor akım değeri
           Ang1 = OrtDgr
        endif  
        if Kanal = 1 then     'Motor hız değeri
           Ang2 = OrtDgr
           if Ang2>= 1001 then Ang2 = 1000
        endif  
        if Kanal = 2 then     'akım sınır değeri
           Ang3 = OrtDgr 
        endif  
        if Kanal = 3 then
           Ang4 = OrtDgr * 5     'Kalkış rampa değeri
           if Ang4 >= 5001 then Ang4 = 5000
        endif  
        if Kanal = 4 then
           Ang5 = OrtDgr * 5     'assağı rampa değeri
           if Ang5 >= 5001 then Ang5 = 5000
        endif  
    next Kanal 
    if ANg1 >= Ang3 then
       high YAkm
    else
       low Yakm
    endif
           
return
'===============================================================================
'===============================================================================