Hd 44780 pbp hd44780 pcf8574 i2c lcd v3

[Tarik konca]

pic basic pro hd44780 2x16 pcf8574 i2c lcd kutuphanesi  v3

Daha once bu linkde

https://etepic.com/index.php?topic=3828.0

ve bu linkde

https://etepic.com/index.php?topic=3830.0

 konu ile ilgili bir yazi yazmistim fakat ogunlerde elimde pcf8574

arayuzlu hd44780 cip setli 2x16 lcd ekran yoktu denemelerimi proteus uzerinde yaparak programi netlestirmistim

uzun zaman sonra elime hazir devre gecti bende daha once yazdigim yaziyi bu devrede denedim

tabiki olmadi cunku pin baglantilari degisikdi bende devredeki pin baglantilarini bularak yeniden

duzenledim sonuc tamam oldu piyasada cogulukla satilan bu urun galiba bir kac yerde rastladim

a0 a1 a2 adresleme pinlerinin yaninda kucuk lehim noktalari var bunlarin ucude sase adresleme

pinleri icerden pull upp li ben bosta biraktim boylece adres 7 oldu siz ayni i2c bus hattinda farkli

urunlerde kullanmak isterseniz ornegin ayni lcd den bir kac tane yada i2c eeprom yada i2c kontrollu ses kayit

ve ses yurutme aygitlari gibi o zaman adresleme hattin da duzenleme yapmaniz gerekiyor

resimlerini ekledim belki satin alipda calistiramayan olursa lazim olur yinede

elinde bu tur devre olan olupta calistiramayan olursa haberleselim yardimci olurum




proteus 8.11

pbp 2.60

ve lcd ekranin resimleri (satin almak isteyenlere yardimci olmak icin)

dosyalar ekde

main program:

'pbp hd44780 pcf8574 i2c lcd v2
'mcu=18f452
DEFINE ADC_BITS 8       ' Set number of bits in result
DEFINE ADC_CLOCK 3     ' Set clock source (rc = 3)
DEFINE ADC_SAMPLEUS 50 ' Set sampling time in microseconds
symbol i2c_data_pin =portc.4
symbol i2c_clock_pin =portc.3
 

sayac var BYTE
temp var Byte
temp_olc var Byte

include "pbp hd44780 pcf8574 i2c lcd.inc"

pause 500
gosub lcd_kur
gosub birinci_satir

for sayac=0 to 14 step 1
LOOKUP sayac,["DEVREM NASILSIN"],temp
rs=1
GoSub lcdgonder
next

voltolc:
ADcIn 0,temp_olc
pause 10
byte_to_string_data=temp_olc:gosub byte_to_string_write
GoTo voltolc
End

kutuphane:

'pbp hd44780 pcf8574 i2c lcd v2
asci_a var Byte
asci_b var Byte
asci_c var Byte
byte_to_string_data var byte
rs var Byte
dur var Byte
lcd_data_port var byte
dur=2

goto kutuphane_cikis

lcd_kur:
rs=0:temp=51:GoSub lcdgonder
temp=50:GoSub lcdgonder
temp=40:GoSub lcdgonder
temp=12:GoSub lcdgonder
temp=3:GoSub lcdgonder
temp=1:GoSub lcdgonder
rs=0:temp=128:GoSub lcdgonder
return

lcdgonder:
lcd_data_port.0=rs
lcd_data_port.1=0 'rw
lcd_data_port.2=1 'en
lcd_data_port.3=1 'Lcd aydinlatma 1 olursa aydilatma yanar 0 olursa soner
lcd_data_port.4=temp.4
lcd_data_port.5=temp.5
lcd_data_port.6=temp.6
lcd_data_port.7=temp.7

I2CWRITE i2c_data_pin,i2c_clock_pin,$4E,[lcd_data_Port]
pause dur
lcd_data_port.2=0 'en
I2CWRITE i2c_data_pin,i2c_clock_pin,$4E,[lcd_data_Port]
pause dur

lcd_data_port.0=rs
lcd_data_port.1=0 'rw
lcd_data_port.2=1 'en
lcd_data_port.3=1 ''Lcd aydinlatma 1 olursa aydilatma yanar 0 olursa soner
lcd_data_port.4=temp.0
lcd_data_port.5=temp.1
lcd_data_port.6=temp.2
lcd_data_port.7=temp.3
I2CWRITE i2c_data_pin,i2c_clock_pin,$4E,[lcd_data_Port]
pause dur
lcd_data_port.2=0
I2CWRITE i2c_data_pin,i2c_clock_pin,$4E,[lcd_data_Port]
pause dur
Return

birinci_satir:
rs=0:temp=128:GoSub lcdgonder
return

ikinci_satir:
rs=0:temp=192:GoSub lcdgonder
return



byte_to_string_write:
asci_a=byte_to_string_data dig 2
asci_b=byte_to_string_data dig 1
asci_c=byte_to_string_data dig 0  
asci_a=asci_a+48
asci_b=asci_b+48
asci_c=asci_c+48
gosub ikinci_satir
rs=1
temp=asci_a
GoSub lcdgonder
temp=asci_b
GoSub lcdgonder
temp=asci_c
GoSub lcdgonder
return

kutuphane_cikis:

[onurinci]

piyasada standart haline geldi, Arduino'cular bunları kullanıyor,saç baş yoluyor yeni başlayanlar.zira çevirici plaketlerde hem pcf8574 ,hemde pcf8574A çıkabiliyor şema aynı olmasına karşılık Adresleri farklı.dikkat etmek gerekiyor..

[dnaci]

Pcf8574T seriside piyasada mevcut onunda adresi farklı. Adresler datasheetleeinde var.

[mehmet]

Katalog okuduktan sonra adresler
problem olmaz.