Etepic

'****************************************************************
'*  Name    : UNTITLED.BAS                                      *
'*  Author  : [select VIEW...EDITOR OPTIONS]                    *
'*  Notice  : Copyright (c) 2021 [select VIEW...EDITOR OPTIONS] *
'*          : All Rights Reserved                               *
'*  Date    : 4.08.2021                                         *
'*  Version : 1.0                                               *
'*  Notes   :                                                   *
'*          :                                                   *
'****************************************************************
'****************************************************************
'*  Name    : UNTITLED.BAS                                      *
'*  Author  : [select VIEW...EDITOR OPTIONS]                    *
'*  Notice  : Copyright (c) 2021 [select VIEW...EDITOR OPTIONS] *
'*          : All Rights Reserved                               *
'*  Date    : 23.07.2021                                        *
'*  Version : 1.0                                               *
'*  Notes   :                                                   *
'*          :                                                   *
'****************************************************************
@ __config _BODEN_OFF  & _PWRTE_ON & _WDT_OFF & _LVP_OFF & _HS_OSC
Define OSC 20
'cmcon = 7
'OPTION_REG=%10001111
'///////////////////////////////////////////////////////////////////////////////   
'/////////////////////////////////////////////////////////////////////////////// 
'ON INTERRUPT GoTo KESME  'kesme oluşursa KESME adlı etikete git.
OPTION_REG=%00000111 'Pull  up dirençleri İPTAL- Bölme oranı 1/64.
'INTCON=%10100000 'Kesmeler  aktif ve TMR0 kesmesi aktif
TMR0=0
CMCON=7 '16F628 de komparatör pinleri iptal hepsi giris çıkıs
'///////////////////////////////////////////////////////////////////////////////   
'///////////////////////////////////////////////////////////////////////////////     
    Trisa            = 0
    TRISB            = %11111100
    Porta            = 0
    Portb            = 255
'///////////////////////////////////////////////////////////////////////////////   
'///////////////////////////////////////////////////////////////////////////////    
    DIO VAR PORTB.1
    CLK VAR PORTB.0
    SDA VAR PORTB.2
    SCL VAR PORTB.3
    symbol Ld       = porta.4
    symbol Bz       = porta.3
    
    Bt1  var Portb.4
    Bt2  var Portb.5
    
'///////////////////////////////////////////////////////////////////////////////   
'///////////////////////////////////////////////////////////////////////////////
'///////////////////////////////////////////////////////////////////////////////  
'///////////////////////////////////////////////////////////////////////////////
    'Zaman için
    AY               var byte
    YIL              var byte
    SN               VAR BYTE
    DAK              VAR BYTE
    SAAT             VAR BYTE
    GUN              VAR BYTE
    HGUN             VAR BYTE
    HAFTA            VAR BYTE
    Temp             var byte
    MEM              var byte
    
    DS_OKU           VAR BYTE : DS_OKU = %11010000
    DS_YAZ           VAR BYTE : DS_YAZ = %11010001
    ZAMAN_REG        VAR BYTE : ZAMAN_REG= $00
    i                var byte
    ZAMAN            var byte[7]
    'TempRegister CON $11      'temperature integer  REGISTER
    TempRegisterFRA  CON $12  'temperature fraction REGISTEr
    TempRegister     var byte    ' variable to hold DS3231 register address to read/write      
    Derece           var byte            ' Variable for temperature integer from register 11h
    Ondalik          var byte          ' Variable for temperature fraction for register 12h
    Isaret           var BYTE            ' Variable to hold sign bit  
    Ds1              var byte
'///////////////////////////////////////////////////////////////////////////////  
'///////////////////////////////////////////////////////////////////////////////   
     CHR1 var byte
     CHR2 var Byte
     CHR3 var byte
     CHR4 var byte
     CMD1 var byte
     CMD2 var byte
     CMD3 var byte
     CMD4 var byte
     Deger var word 

Reset:
high Ld
high Porta.3
CMD1 = $40                     'CMD1=$40 is the write command
CMD2 = $C0                     'CMD2=$C0 is the start digit position(left most)
CMD3 = $88

CHR1 = 0:CHR2 = 64:CHR3 = 64:CHR4 = 0
Gosub AyarEkran
Pause 500
CHR1 = 64:CHR2 = 0:CHR3 = 0:CHR4 = 64
Gosub AyarEkran
Pause 100
CHR1 = 32:CHR2 = 0:CHR3 = 0:CHR4 = 4
Gosub AyarEkran
Pause 100
CHR1 = 1:CHR2 = 0:CHR3 = 0:CHR4 = 8
Gosub AyarEkran
Pause 100
CHR1 = 0:CHR2 = 1:CHR3 = 8:CHR4 = 0
Gosub AyarEkran
Pause 100
CHR1 = 0:CHR2 = 8:CHR3 = 1:CHR4 = 0
Gosub AyarEkran
Pause 100
CHR1 = 16:CHR2 = 0:CHR3 = 0:CHR4 = 2
Gosub AyarEkran
pause 80
'///////////////////////////////////////////////////////////////////////////////     
'///////////////////////////////////////////////////////////////////////////////
basla:
CMD1 = $40                     'CMD1=$40 is the write command
CMD2 = $C0                     'CMD2=$C0 is the start digit position(left most)
CMD3 = $88 
gosub ZAMAN_OKU
'Deger = (Saat * 100) + Dak:gosub LEDOUT'(Saat * 100) + Dak
Deger = (DAK * 100) + Sn:gosub LEDOUT'(Saat * 100) + Dak
pause 1000
goto basla 
'///////////////////////////////////////////////////////////////////////////////     
'///////////////////////////////////////////////////////////////////////////////
AyarEkran:
CMD1 = $40                     'CMD1=$40 is the write command
CMD2 = $C0                     'CMD2=$C0 is the start digit position(left most) 
    GOSUB StartSeq                                  'SHIFTOUT Mode 0 works - LSB first, clock normally low
    SHIFTOUT DIO, CLK, 0, [CMD1]                    'This shifts out the 8-bit write command character $40
    GOSUB AckSeq
    GOSUB StopSeq
    
    GOSUB StartSeq
    SHIFTOUT DIO, CLK, 0, [CMD2]                    'This shifts out the 8-bit command character $C0 that places
    GOSUB AckSeq                                    'the first character CHR1 in the leftmost digit location                             
    SHIFTOUT DIO, CLK, 0, [CHR1]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right   
    GOSUB AckSeq
    SHIFTOUT DIO, CLK, 0, [CHR2]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right   
    GOSUB AckSeq
    SHIFTOUT DIO, CLK, 0, [CHR3]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right   
    GOSUB AckSeq
    SHIFTOUT DIO, CLK, 0, [CHR4]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right   
    GOSUB AckSeq
    GOSUB StopSeq 
    
    GOSUB StartSeq
    SHIFTOUT DIO, CLK, 0, [CMD3]                    'The output sequence ends with CMD3 which turns on the display
    GOSUB AckSeq                                    'and set the brightness duty cyle
    GOSUB StopSeq   
Return

LEDOUT:                                           'This subrountine outputs all 4 characters to the LED
    GOSUB StartSeq                                  'SHIFTOUT Mode 0 works - LSB first, clock normally low
    SHIFTOUT DIO, CLK, 0, [CMD1]                    'This shifts out the 8-bit write command character $40
    GOSUB AckSeq
    GOSUB StopSeq
    
    GOSUB StartSeq
    SHIFTOUT DIO, CLK, 0, [CMD2]                    'This shifts out the 8-bit command character $C0 that places
    GOSUB AckSeq                                    'the first character CHR1 in the leftmost digit location
                                                    'and then writes all 4 digits.
    CHR1 = Deger dig 3  
    Gosub Disp                                             
    SHIFTOUT DIO, CLK, 0, [CHR1]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right
    GOSUB AckSeq                                    'TM1637 auto-increment mode
    CHR1 = Deger dig 2  
    Gosub Disp  
    'if (Ayar = 0 and Pals = 1 ) or Ayar = 1 then CHR1 = Chr1 + 128                                             
    SHIFTOUT DIO, CLK, 0, [CHR1]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right
    GOSUB AckSeq                                    'TM1637 auto-increment mode
    CHR1 = Deger dig 1  
    Gosub Disp                                              
    SHIFTOUT DIO, CLK, 0, [CHR1]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right
    GOSUB AckSeq                                    'TM1637 auto-increment mode
    CHR1 = Deger dig 0  
    Gosub Disp                                              
    SHIFTOUT DIO, CLK, 0, [CHR1]                    'SHIFTOUT CHR1-CHR4 to fill the display left to right
    GOSUB AckSeq                                    'TM1637 auto-increment mode
    GOSUB StopSeq
    
    GOSUB StartSeq
    SHIFTOUT DIO, CLK, 0, [CMD3]                    'The output sequence ends with CMD3 which turns on the display
    GOSUB AckSeq                                    'and set the brightness duty cyle
    GOSUB StopSeq
Return

'****************************************Subroutine StartSeq******************************************************* 
 StartSeq:                                         
   HIGH CLK                                        
   HIGH DIO                                        'The Start sequence takes DIO low and then CLK low 5 uSec later
   'PAUSEUS 5                                       
   LOW DIO
   Low CLK
 Return     

'**************************************Subroutine AckSeq*********************************************************    
 AckSeq:
    LOW CLK 
    High DIO
    High CLK    
    input DIO                                    'The ACK waits for the TM1637 to assert low on DIO
    'PAUSEUS 100                                       'and then replies with a 5 uSec ACK pulse on CLK
    while DIO = 1
    ClearWDt
    wend
    output DIO
    LOW DIO     
 Return

'****************************************Subroutine StopSeq****************************************************** 
 StopSeq:   
    LOW CLK                                        'The stop sequence takes CLK high and then DIO high 5 uSec later
    LOW DIO
    'PAUSEUS 5
    HIGH CLK
    HIGH DIO
 Return
 '///////////////////////////////////////////////////////////////////////////////
'///////////////////////////////////////////////////////////////////////////////
Disp:
lookup CHR1,[$3f,$06,$5b,$4f,$66,$6d,$7d,$07,$7f,$6f,$77,$7c,$39,$5e,$79,$71],CHR1';//0~9,A,b,C,d,E,F],CHR1
return
'///////////////////////////////////////////////////////////////////////////////     
'///////////////////////////////////////////////////////////////////////////////
ZAMAN_OKU:
    i2cread SDA,SCL,DS_OKU,ZAMAN_REG,[ZAMAN[0],ZAMAN[1],ZAMAN[2],ZAMAN[3],ZAMAN[4],ZAMAN[5],ZAMAN[6]]
    GOSUB BCD_To_Decimal
    sn   =ZAMAN[0]
    DAK  =ZAMAN[1]
    SAAT =ZAMAN[2]
    HAFTA=ZAMAN[3]
    GUN  =ZAMAN[4]
    AY   =ZAMAN[5]
    YIL  =ZAMAN[6]  
    TempRegister = $11      ' DS3231 Temperature REgister High Byte (Integer portion)     
    I2Cread SDA,SCL, DS_OKU, TempRegister, [Derece, Ondalik]
    
    Ondalik = (Ondalik >> 6)   ' Shift <b7:b6> to <b1:b0>
    Ondalik = (Ondalik * 25)   ' Fractional portion is in .25 increments. Increment values are 0-3 (.00, .25, .50, .75)
    
    Isaret = "-"
    if derece.7 = 0 then  Isaret = "+"   ' save the sign bit for later
    
    '''If TempSign = 1 then  TempInt = (TempInt XOR $FF) + 1     'Do not use this, the DS3231 uses simple <b7> sign with <b6:b0> as absolute temperature value

RETURN 
'///////////////////////////////////////////////////////////////////////////////   
'///////////////////////////////////////////////////////////////////////////////
ZAMAN_YAZ:

    ZAMAN[0]=sn      ' saniye
    ZAMAN[1]=DAK     ' dakika
    ZAMAN[2]=SAAT    ' saat
    ZAMAN[3]=hafta   ' haftanin gunu
    ZAMAN[4]=gun     ' Gün
    ZAMAN[5]=ay      ' ay
    ZAMAN[6]=yil     ' Yil
    
    GOSUB Decimal_To_BCD

    i2cwrite SDA,SCL,DS_YAZ,ZAMAN_REG,[ZAMAN[0],ZAMAN[1],ZAMAN[2],ZAMAN[3],ZAMAN[4],ZAMAN[5],ZAMAN[6],$10]

return  
'///////////////////////////////////////////////////////////////////////////////   
'///////////////////////////////////////////////////////////////////////////////
DECIMAL_TO_BCD:

    for i=0 to 6
        ZAMAN[i] = ((ZAMAN[i] dig 1) << 4 ) + ZAMAN[i] dig 0
    next i

RETURN
'///////////////////////////////////////////////////////////////////////////////   
'///////////////////////////////////////////////////////////////////////////////
BCD_TO_DECIMAL:

    for i=0 to 6
        ZAMAN[i]   = ((ZAMAN[i] >> 4) *10) + (ZAMAN[i] & %00001111)
    next i

RETURN
'///////////////////////////////////////////////////////////////////////////////