Alarm Saat (picbasic pro, pic16f877, pcf8583)

Serk@n · 10 Kasım 2022, 12:33:06

2. Yolda yıl kullanılmazsa daha kolay oluşturulabilir. Mevcut haliyle oluşturmak biraz zor.

2 yoldaki integerlar önce Mod fonksiyonu ile digitler tespit edilip daha sonra 10,100,1000,10000 ile çarpılıp oluşturulması gerekiyor.

2. yol, if fonksiyonu kullanmaktan daha iyi bir alternatif değil gibi görünüyor.

1. yol biraz daha kullanışlı olabilir. Ama neticede yine de if sorgusuna iki integer giriyor.

transistor · 19 Haziran 2025, 10:51:51

merhabalar ete hocanın saatini yaptım alarm olayını kaldırmak istedim ancak saat düzgün gidiyor sadece saniye, arada bir dakikada birkaç kez sapıtıyor. Sorun nereden kaynaklanabilir?

'****************************************************************
'*  Name    : ALARM-SAAT.BAS                                    *
'*  Author  : [ETE]                                             *
'*  Notice  : Copyright (c) 2005 [ETE]                          *
'*          : All Rights Reserved                               *
'*  Date    : 11.05.2005                                        *
'*  Version : 1.0                                               *
'*  Notes   :                                                   *
'*          :                                                   *
'****************************************************************

'INCLUDE "modedefs.bas"

#CONFIG
cfg = _XT_OSC
cfg&= _WDT_ON
cfg&= _PWRTE_ON
cfg&= _BODEN_OFF
cfg&= _LVP_OFF
cfg&= _CPD_OFF
cfg&= _WRT_OFF
cfg&= _DEBUG_OFF
cfg&= _CP_OFF
  __CONFIG cfg

#ENDCONFIG 
'------------------------------------------------------------------------------
Define osc 4
'------------------------------------------------------------------------------
DEFINE LCD_DREG PORTB      'LCD data bacakları hangi porta bağlı? 
DEFINE LCD_DBIT 4          'LCD data bacakları hangi bitten başlıyor? 
DEFINE LCD_EREG PORTB      'LCD Enable Bacağı Hangi Porta bağlı? 
DEFINE LCD_EBIT 3          'LCD Enable Bacağı Hangi bite bağlı ? 
DEFINE LCD_RSREG PORTB     'LCD RS Bacağı Hangi Porta bağlı ? 
DEFINE LCD_RSBIT 2         'LCD RS bacağı Hangi Bite bağlı ? 
DEFINE LCD_BITS 4          'LCD 4 bit mi yoksa 8 bit olarak bağlı? 
DEFINE LCD_LINES 4         'LCD Kaç sıra yazabiliyor 
'------------------------------------------------------------------------------
ADCON1=7           'ADC GİRİŞLERİ DİGİTAL 
OPTION_REG.7=1    'Dahili pull-up lar iptal edildi
TrisA=%00101111
PortA=0
TrisB=%00000010
PortB=0
TRISD=0 : PORTD=0
TRISC=0 : PORTC=0
'------------------------------------------------------------------------------
SYMBOL MODE=PORTA.1
SYMBOL DOWN=PORTA.2
SYMBOL UP=PORTA.3
Symbol SCL=PORTB.0
SYMBOL SDA=PORTB.1
LCDCLE VAR  BIT
SN     var  byte
Y_SN   VAR  BYTE
DAK    var  byte
Y_DAK  VAR  BYTE
SAAT   var  byte
Y_SAAT VAR  BYTE
GUN    VAR  BYTE
Y_GUN  VAR  BYTE
HGUN   VAR  BYTE  'HAFTANIN GÜNÜ
Y_HGUN var  byte
AY     var  byte
Y_AY   VAR  BYTE
YIL    var  BYTE
Y_YIL  VAR  BYTE
ESKYIL VAR  BYTE
TAMYIL var  BYTE
TEMP   VAR  BYTE
ARA    VAR  BYTE
ONLAR  VAR  BYTE
BIRLER VAR  BYTE
SURE   VAR  BYTE
YER    VAR  BYTE
'-----------------------------------------------------------------------------

lcdout $FE,1
PAUSE 200
SURE=180
LCDCLE=1 
READ 0,TAMYIL
IF TAMYIL=255 THEN
   TAMYIL=4
   WRITE 0,TAMYIL
ENDIF   
Y_SN=0       
'------------------------------------------------------------------------------

BASLA: 
       GOSUB SAAT_OKU
       GOSUB EKRAN
       PAUSE 150 
       IF MODE=0 THEN
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR       
       GOTO AYAR
       ENDIF
       
GOTO BASLA
       
'-------------------------ALT PROGRAMLAR---------------------------------------
AYAR:  
       GOSUB SAAT_OKU
       Y_DAK=DAK : Y_SAAT=SAAT : Y_GUN =GUN : Y_HGUN=HGUN : Y_AY  =AY : Y_YIL =YIL
       GOSUB EKRAN1
 
HOUR:   
       IF MODE=0 THEN
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR
       GOTO MINUTE
       ENDIF
       IF UP=0 THEN
         
         Y_SAAT=Y_SAAT+1
          IF Y_SAAT=24 THEN Y_SAAT=0
       ENDIF        
       
       IF DOWN=0 THEN
         Y_SAAT=Y_SAAT-1
          IF Y_SAAT=255 THEN Y_SAAT=23
       ENDIF
       GOSUB EKRAN1
       LCDOUT $FE,$81
       PAUSE SURE
       GOTO HOUR
             
MINUTE: 
       IF MODE=0 THEN
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR       
       GOTO TAKVIM
       ENDIF
       IF UP=0 THEN
         Y_DAK=Y_DAK+1    
         IF Y_DAK=60 THEN  Y_DAK=0
       ENDIF 
       IF DOWN=0 THEN
         Y_DAK=Y_DAK-1
         IF Y_DAK=255 THEN Y_DAK=59
       ENDIF 
       GOSUB EKRAN1
       LCDOUT $FE,$84
       PAUSE SURE
       GOTO MINUTE 

TAKVIM: 
       IF MODE=0 THEN
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR       
       GOTO MONTH
       ENDIF
       IF UP=0 THEN
         Y_GUN=Y_GUN+1    
         IF Y_GUN=32 THEN  Y_GUN=1
       ENDIF            
       IF DOWN=0 THEN
         Y_GUN=Y_GUN-1    
         IF Y_GUN=0 THEN  Y_GUN=31
       ENDIF 
       GOSUB EKRAN1
       LCDOUT $FE,$C1
       PAUSE SURE 
       GOTO TAKVIM

MONTH:       
       IF MODE=0 THEN
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR       
       GOTO YEAR
       ENDIF
       IF UP=0 THEN
         Y_AY=Y_AY+1    
         IF Y_AY=13 THEN  Y_AY=1
       ENDIF            
       IF DOWN=0 THEN
         Y_AY=Y_AY-1    
         IF Y_AY=0 THEN  Y_AY=12
       ENDIF 
       GOSUB EKRAN1
       LCDOUT $FE,$C4
       PAUSE SURE 
       GOTO MONTH

YEAR:  
       IF MODE=0 THEN
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR
       GOTO HAFGUN
       ENDIF
       IF UP=0 THEN
         Y_YIL=Y_YIL+1    
         IF Y_YIL=100 THEN  Y_YIL=0
       ENDIF            
       IF DOWN=0 THEN
         Y_YIL=Y_YIL-1    
         IF Y_YIL=0 THEN  Y_YIL=99
       ENDIF 
       GOSUB EKRAN1
       LCDOUT $FE,$C7
       PAUSE SURE 
       GOTO YEAR

HAFGUN: 
       IF MODE=0 THEN 
       WHILE MODE=0 : WEND
       LCDCLE=1
       GOSUB LCDCLR
       GOTO KAYIT
       ENDIF
       IF UP=0 THEN
         Y_HGUN=Y_HGUN+1    
         IF Y_HGUN=7 THEN  Y_HGUN=0
       ENDIF            
       IF DOWN=0 THEN
         Y_HGUN=Y_HGUN-1    
         IF Y_HGUN=255 THEN  Y_HGUN=6
       ENDIF 
       GOSUB EKRAN1
       LCDOUT $FE,$C9
       PAUSE SURE 
       GOTO HAFGUN

     GOTO BASLA     
'-------------------------------------------------------------------------------
EKRAN: 
       LCDOUT $FE,2,DEC2(SAAT),":",DEC2(DAK),":", dec2(SN)
       LCDOUT $FE,192,dec2(GUN),"/",dec2(AY),"/",dec2(YIL+TAMYIL) 
       ARA=HGUN 

DORT: select case ARA
        case 0
         lcdout $fe,$c9,"PAZAR    "
       case 1
         lcdout $fe,$c9,"PAZARTESI"
       case 2
         lcdout $fe,$c9,"SALI     "
       case 3
         lcdout $fe,$c9,"CARSAMBA "
       case 4
         lcdout $fe,$c9,"PERSEMBE "
       case 5
         lcdout $fe,$c9,"CUMA     "
       case 6
         lcdout $fe,$c9,"CUMARTESI"
        end select      
       RETURN       

EKRAN1: 'BU EKRAN SAAT AYARINDA KULLANILAN İLK EKRAN
       LCDOUT $FE,$0C,$FE,2,DEC2(Y_SAAT),":",DEC2(Y_DAK);,":", DEC2(SN)
       LCDOUT $FE,192,dec2(Y_GUN),"/",dec2(Y_AY),"/",dec2(Y_YIL+TAMYIL) ,$FE,$0E
        ARA=Y_HGUN
        GOTO DORT
'-------------------------------------------------------------------------------
KAYIT:    
      LCDOUT $FE,$0C     'REG_2  'SANIYE <0:5>
      TEMP=Y_YIL+TAMYIL  'REG_3  'DAKİKA <0:5>
      TAMYIL=4*(TEMP/4 ) 'REG_4  'SAAT   <0:5>
      Y_YIL=TEMP-TAMYIL  'REG_5  'GUN    <0:5> ; YIL  <6:7>  
      WRITE 0,TAMYIL     'REG_6  'AY     <0:4> ; HAFTANIN GUNU <5:7>       
                                                             
DAKHESAP:
      TEMP=Y_DAK:GOSUB HESAP
      Y_DAK=ONLAR+BIRLER
      
SAATHESAP:
      TEMP=Y_SAAT:GOSUB HESAP
      Y_SAAT=ONLAR+BIRLER
      IF TEMP>12 THEN Y_SAAT.6=1
      
GUNHESAP:
       TEMP=Y_GUN:GOSUB HESAP
       Y_YIL=Y_YIL<<6
       Y_GUN=Y_YIL+ONLAR+BIRLER
       
AYHESAP:
       TEMP=Y_AY:GOSUB HESAP
       Y_HGUN=Y_HGUN<<5
       Y_AY=Y_HGUN + ONLAR + BIRLER
                          
      I2CWRITE SDA,SCL,160,2,[Y_SN,Y_DAK,Y_SAAT,Y_GUN,Y_AY]
      GOSUB SAAT_OKU 
      lcdout $fe,1
      GOTO BASLA
HESAP:
      ARA=(TEMP/10)
      ONLAR=ARA<<4
      BIRLER=TEMP-(ara*10)
      RETURN
'-------------------------------------------------------------------------------      
SAAT_OKU:
      ESKYIL=YIL
      I2CREAD SDA,SCL,161,2,[SN,DAK,SAAT,GUN,AY]
      YIL.1=GUN.7
      YIL.0=GUN.6
      IF ESKYIL=3 AND YIL=0 THEN
         TAMYIL=TAMYIL+4
         WRITE 0,TAMYIL
      ENDIF   
      TEMP=AY
      HGUN=TEMP>>5
      SN=SN&%00111111
      TEMP=DAK:gosub BUL:DAK=TEMP
      TEMP=SAAT&%00111111:GOSUB BUL:SAAT=TEMP
      TEMP=GUN&%00111111:GOSUB CEVIR:GUN=TEMP
      TEMP=AY&%00011111:GOSUB IKI:AY=TEMP
      RETURN 

CEVIR:
      ONLAR=TEMP & 48
UC:   ONLAR=(onlar>>4)*10          
BIR:  BIRLER=TEMP & %1111
      TEMP=ONLAR+BIRLER
      RETURN
BUL:ONLAR=(TEMP>>4)*10
      GOTO BIR      
IKI:  ONLAR=ay & 16      
      GOTO UC
'-------------------------------------------------------------------------------
LCDCLR:
      IF LCDCLE=1 THEN
      LCDCLE=0
      LCDOUT $FE,1
      PAUSE 50
      ENDIF
RETURN
'-------------------------------------------------------------------------------      
      end

ete · 19 Haziran 2025, 11:01:31

BASLA satırının aldında yer alan PAUSE 150 satırını PAUSE 50 olarak değiştir tekrar dene.
Yine sorun oluşuyor ise PAUSE 20 ye kadar düşebilirsin.

Ete

transistor · 19 Haziran 2025, 11:46:41

Hocam dediğiniz gibi 20ms ye ye çektim ama saniye; 9. saniyeden 16. saniyeye, 25. saniyeden 32. saniyeye geçiyor 7sn birden. Haftanın 7 günü ile mi alakalı anlayamadım. Simülasyonda da görünüyor. Ama saat de ileri-geri kayma yok.

ete · 19 Haziran 2025, 19:18:17

>Sorun saat Okuma alt programında okunan saniye değerinin ayarlanmasında.
TEMP=SN:GOSUB CEVIR:SN=TEMP şeklinde olması gerekir.
Çünkü SN registeri 8 bitlik ancak %xxxx0000 şeklinde xxxx bitleri saniyenin onlar hanesini tutuyor, kalan 4 bit ise birler hanesini ayarlıyor. Bu nedenle okunan sn değerinin soldan 4 bitini alıp 4 bit sağa kaydırmak ve ardından o sayıyı 10 ile çarpmak gerekir. Sonra buna ilk 4 bit değerini eklemek gerekiyorki GOSUB CEVIR komutu bu işlemi yaptırıyor.
Bu satırı düzelt ve Pause değerini tekrar eski haline getir.

Ete

transistor · 20 Haziran 2025, 08:33:25

söylediğiniz gibi değişiklikleri yaptım aynı şekilde düzelmedi doğru olacağını düşünerek aşağıdaki gibi değişikliğe gittim ama saniye şimdi 39'dan sonra 00 oluyor.

SAAT_OKU:
      ESKYIL=YIL
      I2CREAD SDA,SCL,161,2,[SN,DAK,SAAT,GUN,AY]
      YIL.1=GUN.7
      YIL.0=GUN.6
      IF ESKYIL=3 AND YIL=0 THEN
         TAMYIL=TAMYIL+4
         WRITE 0,TAMYIL
      ENDIF   
      TEMP=AY
      HGUN=TEMP>>5
      TEMP=SN&%00111111:GOSUB CEVIR : SN=TEMP
      TEMP=DAK:gosub BUL:DAK=TEMP
      TEMP=SAAT&%00111111:GOSUB BUL:SAAT=TEMP
      TEMP=GUN&%00111111:GOSUB CEVIR:GUN=TEMP
      TEMP=AY&%00011111:GOSUB IKI:AY=TEMP
      RETURN

ete · 20 Haziran 2025, 08:59:21

Ne söylemişim? TEMP=SN:GOSUB CEVIR:SN=TEMP şeklinde olacak!!!
Sen ne yapmışsın;?
TEMP=SN&%00111111:GOSUB CEVIR : SN=TEMP,
Peki aynısımı benim dediğimin? değil elbette. Şİmdi gelelim ne olduğuna.
SN&%00111111 komutu okunan sn registerinin yalnızca 6 bitini alır diğerlerini dikkate aldırmaz.
Bu 6 bitin 4 adedi (sağdan) zaten birler hanesini oluşturuyor. Kalan 2 bit ne yapabilir ona bakalım
%00 iken onlar hanesi =0
%01 iken onlar hanesi =1
%10 iken onlar hanesi =2
%11 iken onlar hanesi =3 olur başkada alternatif kalmadı o halde senin yaptığınla onlar hanesinde en fazla 3 rakamını görebilirsin daha fazlasını göremezsin.
Belki hala sorunun farkında değilsindir diye tekrarlıyorum onlar hanesi için soldan 4 bitide kullanmak zorundasın. Yalnızca 2 bit eksik görünüme sebep olur.

Neden bazı registerlerin yalnızca 6 bitini kulllanıyoruz (mesela saat gibi) onuda açıklayayım.
Saat registeri onlar hanesi için 2 bit kullanır çünki en fazla göstereceği rakam 2 dir. Bu nedenle solda kalan fazladan 2 bit başka şeyi göstermek için kullanılır. Mesela 6 cı bit 12 saat formatından AM veya PM göstergesidir. 0 ise AM, 1 ise PM. 7. ci bit ise saat formatını saklar. 1 ise saat 12 saat üzerinden çalışır. sıfır ise 24 saat üzerinden çalışır.

5 nolu register olan Yıl/Gun registerinde sağdan ilk 4 bit günlerin birler basamağını tutar. 4 ve 5 nolu bitler Gün değerinin onlar basamağını tutar. Kalan 2 bit ise yıl değerinin 0-3 bilgisini tutar.

	      YIL.1=GUN.7
	      YIL.0=GUN.6
	      IF ESKYIL=3 AND YIL=0 THEN
	         TAMYIL=TAMYIL+4
	         WRITE 0,TAMYIL
	      ENDIF

komutları bu yıl değerini nasıl değerlendirdiğimizi gösteriyor.

Yine 6 nolu register AY bilgisini tutuyor. Ama aynı zamanda haftanın günü değerinide saklıyor. İlk 4 bit Ayların birler basamağını, 4 bit ise ayların onlar basamağını tutuyor. Zira ay/onlar basamak değeri en fazla 1 olabilir. Kalan 3 bit ise haftanın gününe ait oluyor.
Sonuç olarak Data sheet okumayı alışkanlık haline getirmek gerekiyor. Bu bilgilerin hepsini data sheet'e bakarak çıkartıyorum.

Ete

transistor · 20 Haziran 2025, 10:24:34


SAAT_OKU:
      ESKYIL=YIL
      I2CREAD SDA,SCL,161,2,[SN,DAK,SAAT,GUN,AY]
      YIL.1=GUN.7
      YIL.0=GUN.6
      IF ESKYIL=3 AND YIL=0 THEN
         TAMYIL=TAMYIL+4
         WRITE 0,TAMYIL
      ENDIF   
      TEMP=AY
      HGUN=TEMP>>5
      sn=SN&%01111111
      TEMP=SN:GOSUB BUL:SN=TEMP
      TEMP=DAK:gosub BUL:DAK=TEMP
      TEMP=SAAT&%00111111:GOSUB BUL:SAAT=TEMP
      TEMP=GUN&%00111111:GOSUB CEVIR:GUN=TEMP
      TEMP=AY&%00011111:GOSUB IKI:AY=TEMP
      RETURN 

CEVIR:
ONLAR=TEMP & 48

UC:   
ONLAR=(onlar>>4)*10
          
BIR:  
BIRLER=TEMP & %1111
      TEMP=ONLAR+BIRLER
      RETURN

Son cevabınız kafamda bir şeyler canlandırdı. Yardımınız için teşekkür ederim. Bu şekilde bir değişiklikle çalıştırdım. Aklımda şuan iki soru var. 1.'si;

ONLAR=TEMP & 48

kodda ki 48 sayısı ne işe yarıyor? İkincisi,

PCF8583'ün datasheet sayfasına baktığımda max çalışma voltajı 6.0, min çalışma voltajı 2.5V olarak görünüyor.
PCF8583'e 3V pil taktığım zaman ve devre enerjisini kesersem üzerine düşen voltaj 2.8V. Eğer 3.7V pil takarsam enerji yokken ölçtüğüm voltaj 3.5V buna rağmen devrenin enerjisini kestiğimde saat geri kalıyor. 4pin 5V ile çalışan kristal kullanıyorum. PCF8583'ün OSC1 girişinden sinyali giriyorum. OSC2 pini boşta kalıyor. Kristal de 5v olmadığı için muhtemelen geri kalıyor diye düşünüyorum. Pilin + pinini hızlı diyot ile kristalede bağlasam geri kalma olayınıda çözmüş olur muyum? Yoksa kristal 5V'un altında bir enerji ile çalıştığı için(pille) üreteceği frekansta değişiklik olur mu, illa ki 5V mu olmalı, ayrıca 5V kristal ile birlikte pcf8583 enerji yokken tüketeceği voltaj uzun bir süre dayanır mı?

transistor · 20 Haziran 2025, 10:30:04

Doğru söylüyorsunuz datasheet'e bakmıyoruz ingilizce olduğu için o yüzden aksaklıklar peşimizi bırakmıyor. Zaten de elektrikçi olduğum için pek detaylara inemiyorum.

ete · 20 Haziran 2025, 15:46:34

Cevaplar şöyle;
1. soru cevabı: 48 sayısının binary karşılığına bakarsan %00110000 olduğunu görürsün.
ONLAR=TEMP & 48 şeklindeki eşitlik Yalnızca registerin onlar basamağındaki bitleri almak için kullanılıyor burada. Sonarki satırlarda ise bu alınan iki biti 4 bit sağa kaydırıp ve ardından 10 ile çarparak onlar basamağını hesaplıyor program.

2. Soru da eksik bilgi var. Bir kristal (muhtemelen sıcaklık kompanizasyonlu bir osilatör)kullandığını söylüyorsun. Bu osilatörde sıcaklık sorunu olmadığı için her zaman sabit frekans üretebilir ve sistemin enerjisi olduğu müddetçe saat düzgün gider. Enerjiyi kesince ki kimin enerjisini kesmiş oluyorsun onu açıklamamışsın.Şayet hem PCF8586 nın hemde 4 pinli osilatörün enerjisini kesince RTC çalışmayacaktır ve saat geri kalacaktır daha doğrusu kaldığı yerde bekleyecektir. Buda bir nevi geri kalma sayılır. Şayet yalnızca RTC nin enerjisini kesip TCXO nun enerjisini kesmez isen RTC pil üzerinden çalışmasını sürdürür ve yine doğru frekansla beslendiği için geri falan kalmaması gerekir.
Bu durumda kristalin enerjisini kestiğin için saat geri kalıyor teorisi kesinlikle doğru oluyor. O halde yapılacak iş Kristale de pil üzerinden bir besleme verilmesi gerekirki RTC çalışmasına devam edebilsin.
Bana kalırsa bu işi bir dene elindeki kristalin hangi voltajlara kadar çalışabildiğini en azından test et ona göre bir pil bağla.

Bu arada hatırlatayım, DS3231 isimli RTC modülü hem RTC yi hem o kristali hemde pil devresini barındırmaktadır. Bir taşla 3 kuş oluyor bence düşün bunu derim.

Ete

transistor · 21 Haziran 2025, 09:07:38

Yanıtınız için teşekkürler, hocam pili pcf8583'e bağladım ancak kristale de vermeyi akıl etmediğim için saat geri kalıyordu. Pilden kristale de voltaj verince sorun çözüldü. Küçük silindir kristal bulamadım belki de onda sorun olmazdı ama stabilde olmazdı galiba datasheet de ayarlı kondansatör bağlamam gerektiği söyleniyordu. Zaten frekansı ayarlayacak frekansmetre veya osilaskopda yok. Bunu da bilgisayar anakartından mı bir yerden söktüm ama o kadar stabil ki 1 gün oldu 1sn bile kayma yapmamış.

transistor · 21 Haziran 2025, 09:11:00

DS3231 kullandınız mı, içerisinde ki kristal ne kadar stabil? Ancak ds3231 kullanırsam hem sipariş etmem gerekecek hemde beni 3-5 gün erteler çalıştırmam için uzun bir araştırma yapmam gerekebilir.

ete · 21 Haziran 2025, 09:31:12

Artık tamamen DS3231 kullanıyorum. Çünki kendi osilatörü 2.000.000 ppm hassasiyetli sıcaklık korumalı bir osilatör. Senin kullandığını benzeri belkide daha iyisi entegrenin içinde var. Bu 2 milyon sn de 1 sn hata yapar anlamına düşünülebilir. Gerçekte bu ise biraz üzerinde konuşmak gerekir. Bir çok saat yaptım bunlardan bazıları 7-8 senedir hiç ayarlanmadan tam gidiyor. Bunlar eski DS3231 ler ile çalışıyor. Sonradan çıkan çin malı modüllerde mertlik biraz bozulsada yinede diğer RTC lere nazaran daha iyi çalıştıklarını söyleyebilirim. Aslında çok fazla şeye ihtiyaç yok. Sadece okuma kısmı biraz değişecek çok gerekirse ben sana yapıveririm.
Sipariş meselesi sorun ise onu bilemem.

Ete

transistor · 21 Haziran 2025, 12:09:03

Söylediğiniz gibi ilerleyen zamanlarda deneyeceğim. Hem genelde modül olarak satılıyor bir işe entegre etmek daha kolay ve yer kaplamıyor. Ayrıca çok detaylı olarak konusu forumda incelenmiş muhtemelen uygun zamanda ilgili konu başlığını incelersem güzel bir şey çıkarabilirim. Sorun yaşarsam ilgili başlığın altına dönüş yaparım. Yardımınız için çok teşekkür ederim.

transistor · 21 Haziran 2025, 15:43:11

Hocam şimdi birde yılla ilgili sorun yaşıyorum. Yılı set bölümünde ayarladıktan sonra normal ekranda YIL 64 79 09 gibi değerlere ayarlanıyor. Her 2025 yılını set etmeye çalıştığımda farklı yıla ayarlanıyor.